// This Pine Script™ code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © QuantAI-Trend

//@version=6
indicator(title = 'AlphaTrend PRO v.2', overlay = false,max_labels_count = 500,max_lines_count = 500,max_boxes_count = 500,max_bars_back = 1000)


g_switches = "Indicators" 
ms_activate = input(true,"Activate Dynamic Dots",group = g_switches)
ad1_activate = input(true,"Activate Dynamic Reversion Bands",group = g_switches)
linreg_activate = input(false,"Activate Channels",group = g_switches)
ad3_activate = input(false,"Activate Multi-Timeframe Support/Resistance",group = g_switches) 
ad4_activate = input(true,"Activate OverBought/OverSold Banners",group = g_switches)
ad6_activate = input(true,"Activate Areas of Interest",group = g_switches)

g_lowerPane = "Lower Plots"
ad1_plot_stoch = false//input(true,"Plot BCB Stoch",group = g_lowerPane,inline = "bcb") and ms_activate
// ad5_plot_rsiBaseBanker = input(true,"Plot Flow Meter",group = g_lowerPane,inline = "fm")
ad5_plot_bf = input(true,"Plot Banker Flow",group = g_lowerPane,inline = "fm1")
// show_upper = input(true,"Blue",group = g_lowerPane,inline = "fm" )
upper_col = input.color(#5b9cf6,'',group = g_lowerPane,inline = "fm1")
ad5_plot_if = input(false,"Plot Institutional Flow",group = g_lowerPane,inline = "fm2")
// show_lower = input(true,"Yellow",group = g_lowerPane,inline = "fm" )
lower_col = input.color(color.yellow,'',group = g_lowerPane,inline = "fm2") 

//////////////////////////////// MP

ad6_plot_stoch_bg = input(true,"Plot Momentum Pulse",group = g_lowerPane,inline = "fm3")
// show_lower = input(true,"Yellow",group = g_lowerPane,inline = "fm" )
ad6_stoch_bullc = input.color(color.new(color.green,60),'',group = g_lowerPane,inline = "fm3") 
ad6_stoch_bearc = input.color(color.new(color.red,70),'',group = g_lowerPane,inline = "fm3") 
ad6_plot_stoch_sig = input(true,"Crosses",group = g_lowerPane,inline = "fm3")

//////////////////////////// ADX

ad7_plot_sr = input(true,"Plot S/R Factor",group = g_lowerPane)

//////////////////



adx_g = "S/R Settings"
adx_len = 14//input(14,"S/R Length",group = adx_g)
adx_th1 = 11.7//input(11.7,"S/R Upper TH",group = adx_g,inline = "th1")
adx_th2 = 7.5//input(7.5,"Lower TH",group = adx_g,inline = "th1")
adx_plot_dm =  input(true,"Plot S/R Bearish",group = adx_g,inline = "dm") and ad7_plot_sr
adx_dm_bullc = input.color(color.new(color.gray,0),'',group = adx_g,inline = "dm") 
adx_dm_bearc = input.color(color.new(color.yellow,0),'',group = adx_g,inline = "dm") 
const string adx_dm_size = size.small
adx_plot_dp =  input(true,"Plot S/R Bullish",group = adx_g,inline = "dp") and ad7_plot_sr
adx_dp_bullc = input.color(color.new(color.gray,0),'',group = adx_g,inline = "dp") 
adx_dp_bearc = input.color(color.new(color.yellow,0),'',group = adx_g,inline = "dp") 
const string adx_dp_size = size.small

TrueRange = math.max(math.max(high - low, math.abs(high - nz(close[1]))), math.abs(low - nz(close[1])))
DirectionalMovementPlus = high - nz(high[1]) > nz(low[1]) - low ? math.max(high - nz(high[1]), 0) : 0
DirectionalMovementMinus = nz(low[1]) - low > high - nz(high[1]) ? math.max(nz(low[1]) - low, 0) : 0

SmoothedTrueRange = 0.0
SmoothedTrueRange := nz(SmoothedTrueRange[1]) - nz(SmoothedTrueRange[1]) / adx_len + TrueRange

SmoothedDirectionalMovementPlus = 0.0
SmoothedDirectionalMovementPlus := nz(SmoothedDirectionalMovementPlus[1]) - nz(SmoothedDirectionalMovementPlus[1]) / adx_len + DirectionalMovementPlus

SmoothedDirectionalMovementMinus = 0.0
SmoothedDirectionalMovementMinus := nz(SmoothedDirectionalMovementMinus[1]) - nz(SmoothedDirectionalMovementMinus[1]) / adx_len + DirectionalMovementMinus

adx_DIPlus = SmoothedDirectionalMovementPlus / SmoothedTrueRange * 100
adx_DIMinus = SmoothedDirectionalMovementMinus / SmoothedTrueRange * 100
adx_DX = math.abs(adx_DIPlus - adx_DIMinus) / (adx_DIPlus + adx_DIMinus) * 100
ADX = ta.sma(adx_DX, adx_len)

dMinusCol = adx_DIMinus < adx_th1 and adx_DIMinus > adx_th2? adx_dm_bullc : adx_DIMinus < adx_th1 and adx_DIMinus < adx_th2? adx_dm_bearc : na 
plotchar(adx_plot_dm? 25 : na, title="S/R Bearish Factor Line", char="●",location = location.absolute,color=dMinusCol,size=adx_dm_size,editable = false)
dPlusCol = adx_DIPlus < adx_th1 and adx_DIPlus > adx_th2? adx_dp_bullc : adx_DIPlus < adx_th1 and adx_DIPlus < adx_th2? adx_dp_bearc : na 
plotchar(adx_plot_dp? -5 : na, title="D/R Bullish Factor Line", char="●",location = location.absolute,color=dPlusCol,size=adx_dp_size,editable = false)

sr_bull_norm_alert = ta.crossunder(adx_DIPlus,adx_th1)
sr_bull_extreme_alert = ta.crossunder(adx_DIPlus,adx_th2)
sr_bear_norm_alert = ta.crossunder(adx_DIMinus,adx_th1)
sr_bear_extreme_alert = ta.crossunder(adx_DIMinus,adx_th2)

alertcondition( sr_bull_norm_alert , "S/R Factor Bullish Normal", "S/R Factor Bullish Normal @ {{ticker}}")
alertcondition( sr_bull_extreme_alert , "S/R Factor Bullish Extreme", "S/R Factor Bullish Extreme @ {{ticker}}")
alertcondition( sr_bear_norm_alert , "S/R Factor Bearish Normal", "S/R Factor Bearish Normal @ {{ticker}}")
alertcondition( sr_bear_extreme_alert , "S/R Factor Bearish Extreme", "S/R Factor Bearish Extreme @ {{ticker}}")






/////////////////////////

ms_q = 10
ms_r = 3
ms_s = 3
ms_nsig = 3
ms_matype = 'ema' // possible: ema, sma, wma, trima, hma, dema, tema, zlema
ms_overbought = 75
ms_oversold = -75
ms_plot_circles = true

trima(ms_src, ms_length) =>
    ta.sma(ta.sma(ms_src, ms_length), ms_length)
hma(ms_src, ms_length) =>
    ta.wma(2 * ta.wma(ms_src, ms_length / 2) - ta.wma(ms_src, ms_length), math.round(math.sqrt(ms_length)))
dema(ms_src, ms_length) =>
    2 * ta.ema(ms_src, ms_length) - ta.ema(ta.ema(ms_src, ms_length), ms_length)
tema(ms_src, ms_length) =>
    3 * ta.ema(ms_src, ms_length) - 3 * ta.ema(ta.ema(ms_src, ms_length), ms_length) + ta.ema(ta.ema(ta.ema(ms_src, ms_length), ms_length), ms_length)
zlema(ms_src, ms_length) =>
    ta.ema(ms_src, ms_length) + ta.ema(ms_src, ms_length) - ta.ema(ta.ema(ms_src, ms_length), ms_length)

ms_smi = 100 * ta.ema(ta.ema(close - 0.5 * (ta.highest(ms_q) + ta.lowest(ms_q)), ms_r), ms_s) / (0.5 * ta.ema(ta.ema(ta.highest(ms_q) - ta.lowest(ms_q), ms_r), ms_s))
ema_1 = ta.ema(ms_smi, ms_nsig)
sma_1 = ta.sma(ms_smi, ms_nsig)
wma_1 = ta.wma(ms_smi, ms_nsig)
trima__1 = trima(ms_smi, ms_nsig)
hma__1 = hma(ms_smi, ms_nsig)
dema__1 = dema(ms_smi, ms_nsig)
tema__1 = tema(ms_smi, ms_nsig)
zlema__1 = zlema(ms_smi, ms_nsig)
ema_2 = ta.ema(ms_smi, ms_nsig) 
ms_sig = ms_matype == 'ema' ? ema_1 : ms_matype == 'sma' ? sma_1 : ms_matype == 'wma' ? wma_1 : ms_matype == 'trima' ? trima__1 : ms_matype == 'hma' ? hma__1 : ms_matype == 'dema' ? dema__1 : ms_matype == 'tema' ? tema__1 : ms_matype == 'zlema' ? zlema__1 : ema_2

// Mom pulse

// Cross conditions
var mpTrend = 0
co = ta.crossover(ms_smi, ms_sig)
cu = ta.crossunder(ms_smi, ms_sig)
if co
    mpTrend := 1
if cu 
    mpTrend := -1
col = mpTrend == 1 ? ad6_stoch_bullc : mpTrend == -1 ? ad6_stoch_bearc : na
bgcolor(ad6_plot_stoch_bg and ad6_plot_stoch_sig? col : na,title = "Momentum Pulse Background")



////////////

ms_trendlines_g = 'Trendlines'
ms_show_trendlines = input(true, 'Show Trendlines', group = ms_trendlines_g) and ms_activate

dot_size = str.lower(input.string("Auto","Dot Size",options=["Auto","Tiny","Small","Normal","Large","Huge"],group=ms_trendlines_g))
la_sz = input.string('normal', 'label Size', ['tiny', 'small', 'normal', 'large', 'huge'], group = ms_trendlines_g)

ms_length = 14
ms_mult = 1
ms_calcMethod = 'Atr'
ms_backpaint = input(true,"Backpaint", group = ms_trendlines_g)

//Style
ms_upCss = input.color(color.new(color.green,30), 'color', group = ms_trendlines_g)
ms_dnCss = input.color(color.new(color.red,30), 'color', group = ms_trendlines_g)
ms_showExt = input(true, 'Show Extended ms_lines', group = ms_trendlines_g)
ms_lin_w = input.int(2, 'Trendline width', group = ms_trendlines_g)

ms_fomo_white = input.color(color.white,'FOMO CANDLES',inline='col',group = ms_trendlines_g)
ms_fomo_yel = input.color(color.yellow,'',inline='col',group = ms_trendlines_g) 

// Dots 


cSize = size.auto

dotLvl3 = 89
dotLvl2 = 82
dotLvl1 = 74

isTopRedDot = false
isTopYelDot = false
isTopWhiteDot = false

isBotRedDot = false
isBotYelDot = false
isBotWhiteDot = false

if ms_activate and ms_plot_circles
    if ms_smi > dotLvl3
        label.new(bar_index,high,"",yloc = yloc.abovebar,style = label.style_circle,color=color.red,force_overlay = true,size=dot_size)
        isTopRedDot := true
    if ms_smi > dotLvl2 and ms_smi < dotLvl3
        label.new(bar_index,high,"",yloc = yloc.abovebar,style = label.style_circle,color=color.yellow,force_overlay = true,size=dot_size)
        isTopYelDot := true
    if ms_smi > dotLvl1 and ms_smi < dotLvl2
        label.new(bar_index,high,"",yloc = yloc.abovebar,style = label.style_circle,color=color.white,force_overlay = true,size=dot_size)
        isTopWhiteDot := true

    if ms_smi < -dotLvl3
        label.new(bar_index,low,"",yloc = yloc.belowbar,style = label.style_circle,color=color.red,force_overlay = true,size=dot_size)
        isBotRedDot := true
    if ms_smi < -dotLvl2 and ms_smi > -dotLvl3
        label.new(bar_index,low,"",yloc = yloc.belowbar,style = label.style_circle,color=color.yellow,force_overlay = true,size=dot_size)
        isBotYelDot := true
    if ms_smi < -dotLvl1 and ms_smi > -dotLvl2
        label.new(bar_index,low,"",yloc = yloc.belowbar,style = label.style_circle,color=color.white,force_overlay = true,size=dot_size)
        isBotWhiteDot := true

alertcondition( isTopWhiteDot , "Top White Dot", "Top White Dot @ {{ticker}}")
alertcondition( isTopYelDot , "Top Yellow Dot", "Top Yellow Dot @ {{ticker}}")
alertcondition( isTopRedDot , "Top Red Dot", "Top Red Dot @ {{ticker}}")
alertcondition( isBotWhiteDot , "Bottom White Dot", "Bottom White Dot @ {{ticker}}")
alertcondition( isBotYelDot , "Bottom Yellow Dot", "Bottom Yellow Dot @ {{ticker}}")
alertcondition( isBotRedDot , "Bottom Red Dot", "Bottom Red Dot @ {{ticker}}")

var ms_upper = 0.
var ms_lower = 0.
var ms_slope_ph = 0.
var ms_slope_pl = 0.

var ms_offset = ms_backpaint ? ms_length : 0

n = bar_index
ms_src = close

ms_ph = ta.pivothigh(ms_length, ms_length)
ms_pl = ta.pivotlow(ms_length, ms_length)

ms_slope = switch ms_calcMethod
    'Atr' => ta.atr(ms_length) / ms_length * ms_mult
    'Stdev' => ta.stdev(ms_src, ms_length) / ms_length * ms_mult
    'Linreg' => math.abs(ta.sma(ms_src * n, ms_length) - ta.sma(ms_src, ms_length) * ta.sma(n, ms_length)) / ta.variance(n, ms_length) / 2 * ms_mult

ms_slope_ph := bool(ms_ph) ? ms_slope : ms_slope_ph
ms_slope_pl := bool(ms_pl) ? ms_slope : ms_slope_pl

ms_upper := bool(ms_ph) ? ms_ph : ms_upper - ms_slope_ph
ms_lower := bool(ms_pl) ? ms_pl : ms_lower + ms_slope_pl

var upos = 0
var dnos = 0
upos := bool(ms_ph) ? 0 : close > ms_upper - ms_slope_ph * ms_length ? 1 : upos
dnos := bool(ms_pl) ? 0 : close < ms_lower + ms_slope_pl * ms_length ? 1 : dnos

var uptl = line.new(na, na, na, na, color = ms_upCss, style = line.style_solid, extend = extend.right, width = ms_lin_w, force_overlay = true)
var dntl = line.new(na, na, na, na, color = ms_dnCss, style = line.style_solid, extend = extend.right, width = ms_lin_w, force_overlay = true) 

if ms_show_trendlines
    if bool(ms_ph) and ms_showExt
        uptl.set_xy1(n - ms_offset, ms_backpaint ? ms_ph : ms_upper - ms_slope_ph * ms_length)
        uptl.set_xy2(n - ms_offset + 1, ms_backpaint ? ms_ph - ms_slope : ms_upper - ms_slope_ph * (ms_length + 1))

    if bool(ms_pl) and ms_showExt
        dntl.set_xy1(n - ms_offset, ms_backpaint ? ms_pl : ms_lower + ms_slope_pl * ms_length)
        dntl.set_xy2(n - ms_offset + 1, ms_backpaint ? ms_pl + ms_slope : ms_lower + ms_slope_pl * (ms_length + 1))

plot(ms_show_trendlines ? ms_backpaint ? ms_upper : ms_upper - ms_slope_ph * ms_length : na, 'Upper', color = bool(ms_ph) ? na : ms_upCss, offset = -ms_offset, force_overlay = true,linewidth = 2,editable = false,display = display.pane)
plot(ms_show_trendlines ? ms_backpaint ? ms_lower : ms_lower + ms_slope_pl * ms_length : na, 'Lower', color = bool(ms_pl) ? na : ms_dnCss, offset = -ms_offset, force_overlay = true,linewidth = 2,editable = false,display = display.pane)

B_l = ta.atr(14) 
S_l = ta.atr(14) 
if ms_show_trendlines 
    if upos > upos[1]
        label.new(bar_index, low - ( B_l * 4 ), text = 'B', style = label.style_label_up, textcolor = color.white, color = ms_upCss, size = la_sz, force_overlay = true)
    if dnos > dnos[1]
        label.new(bar_index, high + ( S_l * 4 ), text = 'B', style = label.style_label_down, textcolor = color.white, color = ms_dnCss, size = la_sz, force_overlay = true)

alertcondition(upos > upos[1], 'Trendline Upward Breakout', 'Price broke the down trendline upward')
alertcondition(dnos > dnos[1], 'Trendline Downward Breakout', 'Price broke the up trendline downward')


timeframe_option = 'D'
ms_line_color = input.color(#ba68c8, 'Line color', group = 'OPENING PRICE LINE')
ms_line_thickness = 2
ms_line_style = input.string('Solid', 'Line Style', options = ['Solid', 'Dotted', 'Dashed'], group = 'OPENING PRICE LINE')
ms_line_style_enum = ms_line_style == 'Solid' ? line.style_solid : ms_line_style == 'Dotted' ? line.style_dotted : line.style_dashed
ms_show_labels = true
ms_label_color = color.black

ms_open1 = request.security(syminfo.tickerid, timeframe_option, open[2], lookahead = barmerge.lookahead_on)
ms_open2 = request.security(syminfo.tickerid, timeframe_option, open[1], lookahead = barmerge.lookahead_on)
ms_open3 = request.security(syminfo.tickerid, timeframe_option, open, lookahead = barmerge.lookahead_on)

ms_open1_time = request.security(syminfo.tickerid, timeframe_option, time[2], lookahead = barmerge.lookahead_on)
ms_open2_time = request.security(syminfo.tickerid, timeframe_option, time[1], lookahead = barmerge.lookahead_on)
ms_open3_time = request.security(syminfo.tickerid, timeframe_option, time, lookahead = barmerge.lookahead_on)

var array<line> ms_lines = array.new_line(0)
var array<label> ms_labels = array.new_label(0)
int ms_offset_op = na

create_line_and_label(_time, _price, _time2, _text) =>
    var line l = na
    var label lb = na
    l := line.new(_time, _price, _time2 + ms_offset_op, _price, xloc.bar_time, extend.none, ms_line_color, ms_line_style_enum, ms_line_thickness, force_overlay = true)
    array.push(ms_lines, l)
    if ms_show_labels
        lb := label.new(_time2 + ms_offset_op, _price, _text, xloc.bar_time, yloc.price, na, label.style_label_down, ms_label_color, size.small, force_overlay = true)
        array.push(ms_labels, lb)

if ms_activate

    if not na(ms_open1) and not na(ms_open1_time)
        ms_offset_op := 0
        create_line_and_label(ms_open1_time, ms_open1, ms_open2_time, timeframe_option + ' Open 3')

    if not na(ms_open2) and not na(ms_open2_time)
        ms_offset_op := 0
        create_line_and_label(ms_open2_time, ms_open2, ms_open3_time, timeframe_option + ' Open 2')

    if not na(ms_open3) and not na(ms_open3_time)
        ms_offset_op := -20 * (time[1] - time[0])
        create_line_and_label(ms_open3_time, ms_open3, time, timeframe_option + ' Open 1')

lines_count = 3
if array.size(ms_lines) > lines_count
    for i = 0 to array.size(ms_lines) - lines_count - 1 by 1
        line.delete(array.shift(ms_lines))
        if ms_show_labels
            label.delete(array.shift(ms_labels))

ms_len = 7
ms_up = ta.rma(math.max(ta.change(close), 0), ms_len)
ms_down = ta.rma(-math.min(ta.change(close), 0), ms_len)
ms_rsi0 = ms_down == 0 ? 100 : ms_up == 0 ? 0 : 100 - 100 / (1 + ms_up / ms_down)

//coloring method below

ms_len1 = 82
ms_len2 = 18
ms_len3 = 95
ms_len4 = 5
isup() =>
    ms_rsi0 > ms_len1
isdown() =>
    ms_rsi0 < ms_len2

isup1() =>
    ms_rsi0 > ms_len3
isdown1() =>
    ms_rsi0 < ms_len4
barcolor(ms_activate? isup()? ms_fomo_white : isdown() ? ms_fomo_yel : isup1() ? color.aqua : isdown() ? color.orange : na : na,editable = false)


bcb_w_g = "Stock Watermark"
ms_showWM = input.bool(true, 'Show Watermark', group = bcb_w_g,inline = "bcbw") and ms_activate
ms_color = input.color(color.new(color.yellow, 0),"",group = bcb_w_g,inline = "bcbw")
wm_size = str.lower(input.string("Large","Size",options = ["Auto","Tiny","Small","Normal","Large","Huge"],group = bcb_w_g))
i_tableYpos = str.lower(input.string("Top","Location 1",options=["Top","Middle","Bottom"],group=bcb_w_g))
i_tableXpos = str.lower(input.string("Center","Location 2",options=["Left","Center","Right"],group=bcb_w_g))

ms_showTF = true 
ms_showpf = false
// ms_showchange = false
ms_size1 = wm_size

ms_string = '' 
ms_seperator = '/'

ms_cahngeClose = request.security(syminfo.tickerid, timeframe.period, close)

ms_cur = syminfo.currency
ms_base = syminfo.basecurrency
ms_exchange = syminfo.prefix


getTimeFrame() =>
    tf = timeframe.multiplier
    tfstr = ''
    if timeframe.isseconds
        tfstr := 'ms_s'
        tfstr
    if timeframe.isminutes
        if tf >= 60
            tf := tf / 60
            tfstr := 'h'
            tfstr
        else
            tfstr := 'm'
            tfstr
    if timeframe.isdaily
        tfstr := 'D'
        tfstr
    if timeframe.isweekly
        tfstr := 'W'
        tfstr
    if timeframe.ismonthly
        tfstr := 'M'
        tfstr

    [tfstr, str.tostring(tf)]

var table ms_table1 = table.new(i_tableYpos + '_' + i_tableXpos, 4, 1, force_overlay = true)

if barstate.islast and ms_showWM
    str1 = ms_base != '' ? ms_base + ms_seperator + ms_cur : syminfo.ticker
    [tf, period] = getTimeFrame()

    change = math.round((ms_cahngeClose[0] / ms_cahngeClose[1] - 1) * 100, 2)
    changeStr = ''
    if change > 0
        changeStr := '▲' + str.tostring(math.abs(change)) + '%' 
        changeStr
    else
        changeStr := '▼' + str.tostring(math.abs(change)) + '%'
        changeStr



    table.cell(ms_table1, 1, 0, str1 + (ms_showTF ? ' ' + period + tf : ''), width = 0, text_color = ms_color, text_size = ms_size1)


/////////////////////////////// AD1
 
ad1_g = "A.I. Bands"
ad1_length = 500
ad1_h      = 8
ad1_mult   = 2.2
ad1_src    = close

ad1_plot_tri = false//input(false,"Plot triangels",group = ad1_g)
ad1_up_col = input.color(color.rgb(132, 55, 164),'Bands Colors',inline='col',group = ad1_g)
ad1_dn_col = input.color(color.rgb(132, 55, 164),'',inline='col',group = ad1_g) 

////////////////////////////////////////////////////////////////////////////////

//----
var ad1_k = 2 
var ad1_upper = array.new_line(0)  
var ad1_lower = array.new_line(0) 
//----
ad1_cross_up = 0.
ad1_cross_dn = 0.

lset(l,x1,y1,x2,y2,col)=>
    line.set_xy1(l,x1,y1)
    line.set_xy2(l,x2,y2)
    line.set_color(l,col)
    line.set_width(l,2)

if ad1_activate    

    if barstate.isfirst
        for i = 0 to ad1_length/ad1_k-1
            array.unshift(ad1_upper,line.new(na,na,na,na,force_overlay = true))
            array.unshift(ad1_lower,line.new(na,na,na,na,force_overlay = true))
    //----
    line ad1_up = na
    line ad1_dn = na
    if barstate.islast
        y = array.new_float(0)
        
        sum_e = 0.
        for i = 0 to ad1_length-1
            sum = 0.
            sumw = 0.
            
            for j = 0 to ad1_length-1
                w = math.exp(-(math.pow(i-j,2)/(ad1_h*ad1_h*2)))
                sum += ad1_src[j]*w
                sumw += w
            
            y2 = sum/sumw
            sum_e += math.abs(ad1_src[i] - y2)
            array.push(y,y2)

        mae = sum_e/ad1_length*ad1_mult


        for i = 1 to ad1_length-1
            len = 2 
            y2 = array.get(y,i)
            y1 = array.get(y,i-(i==1? 1 : len))
            
            ad1_up := array.get(ad1_upper,i/ad1_k)
            ad1_dn := array.get(ad1_lower,i/ad1_k) 
            
            lset(ad1_up,n-i+(i==1? 1 : len),y1 + mae,n-i,y2 + mae,ad1_up_col)
            lset(ad1_dn,n-i+(i==1? 1 : len),y1 - mae,n-i,y2 - mae,ad1_dn_col)
 
            j = i-1 
            
            if ad1_src[j] > (y1 + mae) and ad1_src[j+1] < (y1 + mae) and ad1_plot_tri
                label.new(n-j,ad1_src[j]+ ( B_l * 1 ),'▼',color=#00000000,style=label.style_label_down,textcolor=color.white,textalign=text.align_center,force_overlay = true)
            if ad1_src[j] < (y1 - mae) and ad1_src[j+1] > (y1 - mae) and ad1_plot_tri
                label.new(n-j,ad1_src[j]- ( S_l * 1 ),'▲',color=#00000000,style=label.style_label_up,textcolor=color.white,textalign=text.align_center,force_overlay = true)
         
        ad1_cross_up := array.get(y,0) + mae
        ad1_cross_dn := array.get(y,0) - mae

// alertcondition(ta.crossover(ad1_src,ad1_cross_up),'BHN Down','BHN Down')
// alertcondition(ta.crossunder(ad1_src,ad1_cross_dn),'BHN Up','BHN UP') 


///////////////////////////// AD2

// ad2_g = "/////////// LRA Channels"
ad2_lengthInput = 100//input.int(100, title = 'Length', minval = 1, maxval = 5000,group=ad2_g)
ad2_sourceInput = close//input.source(close, title = 'Source',group=ad2_g)

ad2_useUpperDevInput = true
ad2_upperMultInput = 2.0
ad2_useLowerDevInput = true
ad2_lowerMultInput = 2.0
 
ad2_group2 = 'Linear Regression Settings'
ad2_showPearsonInput = false
ad2_extendLeftInput = input.bool(false, 'Extend Lines Left', group = ad2_group2)
ad2_extendRightInput = input.bool(false, 'Extend Lines Right', group = ad2_group2)
ad2_extendStyle = switch 
    ad2_extendLeftInput and ad2_extendRightInput => extend.both
    ad2_extendLeftInput => extend.left
    ad2_extendRightInput => extend.right
    => extend.none

ad2_colorUpper = input.color(color.new(color.lime,85), 'LRA Color Settings', group = ad2_group2,inline = "lracol")
ad2_colorLower = input.color(color.new(color.red, 85), '', group = ad2_group2,inline = "lracol")

calcSlope(source, length) =>
    max_bars_back(source, 5000)
    if not barstate.islast or length <= 1
        [float(na), float(na), float(na)]
    else
        sumX = 0.0
        sumY = 0.0
        sumXSqr = 0.0
        sumXY = 0.0
        for i = 0 to length - 1 by 1
            val = source[i]
            per = i + 1.0
            sumX := sumX + per
            sumY := sumY + val
            sumXSqr := sumXSqr + per * per
            sumXY := sumXY + val * per
            sumXY
        slope = (length * sumXY - sumX * sumY) / (length * sumXSqr - sumX * sumX)
        average = sumY / length
        intercept = average - slope * sumX / length + slope
        [slope, average, intercept]

calcDev(source, length, slope, average, intercept) =>
    ad2_upDev = 0.0
    ad2_dnDev = 0.0
    stdDevAcc = 0.0
    dsxx = 0.0
    dsyy = 0.0
    dsxy = 0.0
    periods = length - 1
    daY = intercept + slope * periods / 2
    val = intercept
    for j = 0 to periods by 1
        price = high[j] - val
        if price > ad2_upDev
            ad2_upDev := price
            ad2_upDev
        price := val - low[j]
        if price > ad2_dnDev
            ad2_dnDev := price
            ad2_dnDev
        price := source[j]
        dxt = price - average
        dyt = val - daY
        price := price - val
        stdDevAcc := stdDevAcc + price * price
        dsxx := dsxx + dxt * dxt
        dsyy := dsyy + dyt * dyt
        dsxy := dsxy + dxt * dyt
        val := val + slope
        val
    ad2_stdDev = math.sqrt(stdDevAcc / (periods == 0 ? 1 : periods))
    ad2_pearsonR = dsxx == 0 or dsyy == 0 ? 0 : dsxy / math.sqrt(dsxx * dsyy)
    [ad2_stdDev, ad2_pearsonR, ad2_upDev, ad2_dnDev]

float ad2_trend = 0.0
var line ad2_upper = na
var line ad2_lower = na

if linreg_activate
    [s, a, i] = calcSlope(ad2_sourceInput, ad2_lengthInput)
    ad2_startPrice = i + s * (ad2_lengthInput - 1)
    ad2_endPrice = i
    var line ad2_baseLine = na
    if na(ad2_baseLine) and not na(ad2_startPrice)
        ad2_baseLine := line.new(bar_index - ad2_lengthInput + 1, ad2_startPrice, bar_index, ad2_endPrice, width = 1, extend = ad2_extendStyle, color = ad2_colorLower,force_overlay = true)
        ad2_baseLine
    else
        line.set_xy1(ad2_baseLine, bar_index - ad2_lengthInput + 1, ad2_startPrice)
        line.set_xy2(ad2_baseLine, bar_index, ad2_endPrice)
        na


    [ad2_stdDev, ad2_pearsonR, ad2_upDev, ad2_dnDev] = calcDev(ad2_sourceInput, ad2_lengthInput, s, a, i)
    ad2_upperStartPrice = ad2_startPrice + (ad2_useUpperDevInput ? ad2_upperMultInput * ad2_stdDev : ad2_upDev)
    ad2_upperEndPrice = ad2_endPrice + (ad2_useUpperDevInput ? ad2_upperMultInput * ad2_stdDev : ad2_upDev)
    ad2_lowerStartPrice = ad2_startPrice + (ad2_useLowerDevInput ? -ad2_lowerMultInput * ad2_stdDev : -ad2_dnDev)
    ad2_lowerEndPrice = ad2_endPrice + (ad2_useLowerDevInput ? -ad2_lowerMultInput * ad2_stdDev : -ad2_dnDev)
    if na(ad2_upper) and not na(ad2_upperStartPrice)
        ad2_upper := line.new(bar_index - ad2_lengthInput + 1, ad2_upperStartPrice, bar_index, ad2_upperEndPrice, width = 1, extend = ad2_extendStyle, color = ad2_colorUpper,force_overlay = true)
        ad2_upper
    else
        line.set_xy1(ad2_upper, bar_index - ad2_lengthInput + 1, ad2_upperStartPrice)
        line.set_xy2(ad2_upper, bar_index, ad2_upperEndPrice)
        na
    if na(ad2_lower) and not na(ad2_lowerStartPrice)
        ad2_lower := line.new(bar_index - ad2_lengthInput + 1, ad2_lowerStartPrice, bar_index, ad2_lowerEndPrice, width = 1, extend = ad2_extendStyle, color = ad2_colorUpper,force_overlay = true)
        ad2_lower
    else
        line.set_xy1(ad2_lower, bar_index - ad2_lengthInput + 1, ad2_lowerStartPrice)
        line.set_xy2(ad2_lower, bar_index, ad2_lowerEndPrice)
        na
    linefill.new(ad2_upper, ad2_baseLine, color = ad2_colorUpper)
    linefill.new(ad2_baseLine, ad2_lower, color = ad2_colorLower)

    ad2_trend := math.sign(ad2_startPrice - ad2_endPrice)

    // Pearson's R
    var label ad2_r = na
    label.delete(ad2_r[1])
    if ad2_showPearsonInput and not na(ad2_pearsonR)
        ad2_r := label.new(bar_index - ad2_lengthInput + 1, ad2_lowerStartPrice, str.tostring(ad2_pearsonR, '#.################'), color = color.new(color.white, 100), textcolor = ad2_colorUpper, size = size.normal, style = label.style_label_up,force_overlay = true)
        ad2_r
    

alertcondition(ad2_sourceInput > line.get_price(ad2_upper, bar_index) or ad2_sourceInput < line.get_price(ad2_lower, bar_index), title = 'LRA Regression Channel Exited', message = 'The price movement has exited Regression Channel\'s bounds')
alertcondition(ad2_trend[1] >= 0 and ad2_trend < 0, title = 'LRA Regression Channel Uptrend', message = 'The Regression Channel Trend switched from Downtrend to Uptrend')
alertcondition(ad2_trend[1] <= 0 and ad2_trend > 0, title = 'LRA Regression Channel Downtrend', message = 'The Regression Channel Trend switched from Uptrend to Downtrend')

//////////////////////////// AD3

sr_line_trans = 30
sr_trackprice = true

ad3_left = 5
ad3_right = 5
ad3_line_width = 3

ad3_sr_g = "/////////// Support/Resistance Timeframes"
ad3_activeATF = input.bool(false, "Current Timeframe", group=ad3_sr_g, inline="", tooltip="Show you current timeframe support and resistance levels")

ad3_activeD = input.bool(false, "Daily  ", group=ad3_sr_g, inline="sr-a")
ad3_active4h = input.bool(true, "4 Hour  ", group=ad3_sr_g, inline="sr-a")
ad3_active1h = input.bool(false, "1 Hour  ", group=ad3_sr_g, inline="sr-a")
ad3_active30m = input.bool(false, "M30   ", group=ad3_sr_g, inline="sr-b")
ad3_active15m = input.bool(true, "M15    ", group=ad3_sr_g, inline="sr-b")
ad3_active5m = input.bool(false, "M5", group=ad3_sr_g, inline="sr-b")
sr_line_style = input.string(line.style_solid,"Line Style",options = [line.style_solid,line.style_dashed,line.style_dotted],group=ad3_sr_g)
ad3_lbl_size = str.lower(input.string("Small","Label Size",options=["Auto","Tiny","Small","Normal","Large","Huge"],group=ad3_sr_g))

ad3_sr_color = input.color(color.new(#b8bbc0, 50), "S/R Color", group="S/R Colors") 
ad3_c_white = input.color(color.new(color.white, 50), "Label Color", group="S/R Colors") 

pivot_tf_high(tf, src, ad3_left, ad3_right, occ) =>
    request.security(syminfo.tickerid, tf, ta.valuewhen(not na(ta.pivothigh(src, ad3_left, ad3_right)), close[ad3_right], 0))

pivot_tf_low(tf, src, ad3_left, ad3_right, occ) =>
    request.security(syminfo.tickerid, tf, ta.valuewhen(not na(ta.pivotlow(src, ad3_left, ad3_right)), close[ad3_right], 0))



create_line_label(lvl, lvl2, txt)=>
    l1 = line.new(x1=bar_index - 1, y1=lvl, x2=bar_index, y2=lvl, extend=extend.both, width=ad3_line_width, color=ad3_sr_color,force_overlay = true,style = sr_line_style)
    l2 = line.new(x1=bar_index - 1, y1=lvl2, x2=bar_index, y2=lvl2, extend=extend.both, width=ad3_line_width, color=ad3_sr_color,force_overlay = true,style = sr_line_style)
    line.delete(l1[1])
    line.delete(l2[1])
    if not na(lvl)
        lab = label.new(bar_index + 5, lvl, text=txt, style=label.style_none, textcolor=ad3_c_white,force_overlay = true,size = ad3_lbl_size )
        label.delete(lab[1])
    if not na(lvl2)
        lab2 = label.new(bar_index + 5, lvl2, text=txt, style=label.style_none, textcolor=ad3_c_white,force_overlay = true,size = ad3_lbl_size )
        label.delete(lab2[1])

 
if ad3_activate

    float level1 = na
    float level2 = na
    float level3 = na
    float level4 = na
    float level5 = na
    float level6 = na
    float level7 = na
    float level8 = na
    float level9 = na
    float level0 = na

    float level15m = na
    float level15m1 = na

    float level5m = na
    float level5m1 = na

    if ad3_activeATF
        level1 := ta.valuewhen(not na(ta.pivothigh(close, ad3_left, ad3_right)), close[ad3_right], 0)
        level2 := ta.valuewhen(not na(ta.pivotlow(close, ad3_left, ad3_right)), close[ad3_right], 0)

    if timeframe.isintraday
        if ad3_active4h
            level3 := pivot_tf_high('240', close, ad3_left, ad3_right, 0)
            level4 := pivot_tf_low('240', close, ad3_left, ad3_right, 0)

        if ad3_active1h
            level5 := pivot_tf_high('60', close, ad3_left, ad3_right, 0)
            level6 := pivot_tf_low('60', close, ad3_left, ad3_right, 0)
        
        if ad3_active30m
            level7 := pivot_tf_high('30', close, ad3_left, ad3_right, 0)
            level8 := pivot_tf_low('30', close, ad3_left, ad3_right, 0)
        
        if ad3_active15m
            level15m := pivot_tf_high('15', close, ad3_left, ad3_right, 0)
            level15m1 := pivot_tf_low('15', close, ad3_left, ad3_right, 0)
        
        if ad3_active5m
            level5m := pivot_tf_high('5', close, ad3_left, ad3_right, 0)
            level5m1 := pivot_tf_low('5', close, ad3_left, ad3_right, 0)

        if ad3_activeD
            level9 := pivot_tf_high('D', close, ad3_left, ad3_right, 0)
            level0 := pivot_tf_low('D', close, ad3_left, ad3_right, 0)
            level0


    //Only show the strongest support/resistance levels
    if level5 == level7
        level7 := na
    if level6 == level8
        level8 := na
        
    if level1 == level3 or level1 == level5 or level1 == level7 or level1 == level9 or level1 == level15m or level1 == level15m1 or level1 == level5m or level1 == level5m1
        level1 := na
    if level2 == level4 or level2 == level6 or level2 == level8 or level2 == level0 or level2 == level15m or level2 == level15m1 or level2 == level5m or level2 == level5m1
        level2 := na
        
    if level15m == level3 or level15m == level4 or level15m == level5 or level15m == level6 or level15m == level7 or level15m == level8
        level15m := na
    if level15m1 == level3 or level15m1 == level4 or level15m1 == level5 or level15m1 == level6 or level15m1 == level7 or level15m1 == level8
        level15m1 := na
        
    if level5m == level3 or level5m == level4 or level5m == level5 or level5m == level6 or level5m == level7 or level5m == level8 or level5m == level15m1 or level5m == level15m
        level5m := na

    if level5m1 == level3 or level5m1 == level4 or level5m1 == level5 or level5m1 == level6 or level5m1 == level7 or level5m1 == level8 or level5m1 == level15m1 or level5m1 == level15m
        level5m1 := na

        
    if barstate.islast
        create_line_label(level1, level2, "ATF")
        create_line_label(level3, level4, "H4")
        create_line_label(level5, level6, "H1")
        create_line_label(level7, level8, "M30")
        create_line_label(level15m, level15m1, "M15")
        create_line_label(level5m, level5m1, "M5")
        create_line_label(level0, level9, "D")
        
///////////////// AD4
 
ad4_rsiL = 7
ad4_rsiOBI = 83
ad4_rsiOSI = 17
ad4_fibLevel = 0.333
ad4_BullBearEngulf = true

ad4_TradeSignal = false
ad4_bullE = false
ad4_bearE = false

if ad4_activate

    //RSI VALUE
    myRsi = ta.rsi(close , ad4_rsiL)

    //RSI OVERBOUGHT / OVERSOLD
    rsiOB = myRsi >= ad4_rsiOBI
    rsiOS = myRsi <= ad4_rsiOSI

    ///////////=Hammer & Shooting star=/////////////

    bullFib = (low - high) * ad4_fibLevel + high
    bearFib = (high - low) * ad4_fibLevel + low

    // Determine which price source closses or open highest/lowest
    bearCandle = close < open ? close : open
    bullCandle = close > open ? close : open 

    // Determine if we have a valid hammer or shooting star
    hammer = (bearCandle >= bullFib) and rsiOS
    shooting = (bullCandle <= bearFib) and rsiOB

    twoGreenBars = (close > open and close[1] > open[1]) and rsiOS
    twoRedBars = (close < open and close[1] < open[1]) and rsiOB

    /////////////////////////////////////////////

    // Engulfing candles
    ad4_bullE := (close > open[1] and close[1] < open[1])
    //or hammer or twoGreenBars 
    
    ad4_bearE := close < open[1] and close[1] > open[1]
    //or shooting or twoRedBars 

    ///////////////////////////////////////////

    // ((x) y) farmula defination is: X is gona be executed before Y,
    ad4_TradeSignal := ((rsiOS or rsiOS[1]) and ad4_bullE) or ((rsiOB or rsiOB[1]) and ad4_bearE)

    if (ad4_TradeSignal and ad4_bearE and ad4_BullBearEngulf)
        label.new(x= bar_index, y= na, text="HIGH", yloc= yloc.abovebar,color= color.blue, textcolor= color.white, style= label.style_label_down, size=size.small,force_overlay = true)

    if (ad4_TradeSignal and ad4_bullE and ad4_BullBearEngulf)
        label.new(x= bar_index, y= na, text="LOW", yloc= yloc.belowbar,color= color.green, textcolor= color.white, style= label.style_label_up, size=size.small,force_overlay = true)

// Send Alert if Candle meets our condition
plotshape(ad4_TradeSignal and ad4_bearE and ad4_BullBearEngulf, title="OB/OS Overbought", location=location.abovebar, color=color.orange, style=shape.triangledown, size=size.auto, text="",force_overlay = true,editable = false,display = display.pane)
plotshape(ad4_TradeSignal and ad4_bullE and ad4_BullBearEngulf, title="OB/OS Oversold", location=location.belowbar, color=color.lime, style=shape.triangleup, size=size.auto, text="",force_overlay = true,editable = false,display = display.pane)
alertcondition(ad4_TradeSignal, title="Overbought/Oversold Signal", message="RSI Signal Detected fot {{ticker}}")

////////////////////////////// AD5
 
RSIBaseBanker       = 50
RSIPeriodBanker     = 50
RSIBaseHotMoney     = 30
RSIPeriodHotMoney   = 40
SensitivityBanker   = 1.5
SensitivityHotMoney = 0.7

rsi_function(sensitivity, rsiPeriod, rsiBase) =>
    rsi = sensitivity * (ta.rsi(close, rsiPeriod) - rsiBase)
    if rsi > 20
        rsi := 20
    else if rsi < 0
        rsi := 0
    rsi

rsi_Banker   = rsi_function(SensitivityBanker,   RSIPeriodBanker,   RSIBaseBanker)
rsi_HotMoney = rsi_function(SensitivityHotMoney, RSIPeriodHotMoney, RSIBaseHotMoney)
 

// plot(ad5_plot_rsiBaseBanker?20 : na,           "RETAIL MONEY",  #005e07, 1, plot.style_line, editable = false,display = display.pane)
plot(ad5_plot_if?rsi_Banker : na,   "INSTITUIONAL MONEY", lower_col, 1, plot.style_line, editable = false,display = display.pane)
plot(ad5_plot_bf?rsi_HotMoney : na, "PROFESSIONAL MONEY", upper_col, 1, plot.style_line, editable = false,display = display.pane)

if (ad5_plot_if or ad5_plot_bf) and barstate.isfirst
    line.new(bar_index-1,0,bar_index,0,color=color.new(color.silver,60),style=line.style_solid,extend = extend.both)
    line.new(bar_index-1,5,bar_index,5,color=color.new(color.silver,60),style=line.style_solid,extend = extend.both)
    line.new(bar_index-1,10,bar_index,10,color=color.new(color.fuchsia,60),style=line.style_solid,extend = extend.both) 
    line.new(bar_index-1,15,bar_index,15,color=color.new(color.silver,60),style=line.style_solid,extend = extend.both)
    line.new(bar_index-1,20,bar_index,20,color=color.new(color.silver,60),style=line.style_solid,extend = extend.both)

textCol = color.white
txtSize = size.small
labelCol = color.black
var table bbTable = na 
if barstate.isfirst and (ad5_plot_if or ad5_plot_bf)
    bbTable := table.new(position.bottom_left,frame_color=color.black,bgcolor=color.new(color.white,100),border_color=color.new(color.white,100), columns=2, rows=2, border_width=3)
    
    if ad5_plot_bf
        table.cell(table_id=bbTable, column=0, row=0, text="B", text_halign=text.align_center,text_color=textCol,text_size=str.lower(txtSize), text_valign= text.align_center, bgcolor=labelCol)
        table.cell(table_id=bbTable, column=1, row=0, text="", text_halign=text.align_right,text_color=textCol,text_size=str.lower(txtSize), text_valign= text.align_center, bgcolor=upper_col,width = 4)

    if ad5_plot_if
        table.cell(table_id=bbTable, column=0, row=1, text="I", text_halign=text.align_center,text_color=textCol,text_size=str.lower(txtSize), text_valign= text.align_center, bgcolor=labelCol)
        table.cell(table_id=bbTable, column=1, row=1, text="", text_halign=text.align_right,text_color=textCol,text_size=str.lower(txtSize), text_valign= text.align_center, bgcolor=lower_col,width = 4)
 
 
// hline(ad5_plot_rsiBaseBanker?  5 : na, "5" , color.silver,  linewidth=1,linestyle = hline.style_dashed, editable = false)
// hline(ad5_plot_rsiBaseBanker? 10 : na, "10", color.fuchsia, linewidth=1,linestyle = hline.style_solid, editable = false)
// hline(ad5_plot_rsiBaseBanker? 15 : na, "15", color.silver,  linewidth=1,linestyle = hline.style_dashed, editable = false) 

///////////////////////////// AD6

//      INDICATOR SETTINGS
ad6_swing_length = 10
history_of_demand_to_keep = 20
ad6_box_width = 2.5

//      INDICATOR VISUAL SETTINGS
ad6_v_g = 'Visual Settings'
ad6_show_zigzag = false//input.bool(false, title = 'Show Zig Zag', group = ad6_v_g, inline = '1') 
show_price_action_labels = input.bool(true, title = 'Show Price Action Labels', group = ad6_v_g, inline = '2')
 
poi_label_color = input.color(color.white, title = 'Zone Label', group = ad6_v_g, inline = '7')

ad6_supply_color = input.color(color.new(#752b10, 50), title = 'SUPPLY ZONE', group = ad6_v_g, inline = '3')
ad6_supply_outline_color = input.color(color.new(#752b10, 50), title = 'Outline', group = ad6_v_g, inline = '3')

ad6_demand_color = input.color(color.new(color.gray, 50), title = 'DEMAND ZONE', group = ad6_v_g, inline = '4') 
demand_outline_color = input.color(color.new(color.gray, 50), title = 'Outline', group = ad6_v_g, inline = '4')

bos_label_color = input.color(color.white, title = 'BOS Label', group = ad6_v_g, inline = '5')
bos_bull_line_color = input.color(color.new(color.gray,75), title = 'Line', group = ad6_v_g, inline = '5')
bos_bear_line_color = input.color(color.new(color.red,75), title = 'Line', group = ad6_v_g, inline = '5')


swing_type_color = input.color(color.rgb(89, 154, 203), title = 'Price Action Label', group = ad6_v_g, inline = '8')
ad6_zigzag_color = color.new(#da8e8e, 0)//input.color(color.new(#000000, 0), title = 'Zig Zag', group = 'Visual Settings', inline = '9')
ad6_pa_lbl_size = str.lower(input.string("Normal","",options = ["Tiny","Small","Normal","Large","Huge"],group = ad6_v_g, inline = '8'))
//      FUNCTION TO ADD NEW AND REMOVE LAST IN ARRAY 
f_array_add_pop(array, new_value_to_add) =>
    array.unshift(array, new_value_to_add)
    array.pop(array)

//      FUNCTION SWING H & L LABELS 
f_sh_sl_labels(array, swing_type) =>

    var string label_text = na
    if swing_type == 1
        if array.get(array, 0) >= array.get(array, 1)
            label_text := 'HH'
            label_text
        else
            label_text := 'LH'
            label_text
        label.new(bar_index - ad6_swing_length, array.get(array, 0), text = label_text, style = label.style_label_down, textcolor = swing_type_color, color = color.new(color.white, 100), size = ad6_pa_lbl_size,force_overlay = true)

    else if swing_type == -1
        if array.get(array, 0) >= array.get(array, 1)
            label_text := 'HL'
            label_text
        else
            label_text := 'LL'
            label_text
        label.new(bar_index - ad6_swing_length, array.get(array, 0), text = label_text, style = label.style_label_up, textcolor = swing_type_color, color = color.new(color.white, 100), size = ad6_pa_lbl_size,force_overlay = true)

//      FUNCTION MAKE SURE SUPPLY ISNT OVERLAPPING
f_check_overlapping(new_poi, box_array, ad6_atr) =>

    atr_threshold = ad6_atr * 2
    okay_to_draw = true

    for i = 0 to array.size(box_array) - 1 by 1
        top = box.get_top(array.get(box_array, i))
        bottom = box.get_bottom(array.get(box_array, i))
        poi = (top + bottom) / 2

        upper_boundary = poi + atr_threshold
        lower_boundary = poi - atr_threshold

        if new_poi >= lower_boundary and new_poi <= upper_boundary
            okay_to_draw := false
            break
        else
            okay_to_draw := true
            okay_to_draw
    okay_to_draw


//      FUNCTION TO DRAW SUPPLY OR DEMAND ZONE
f_supply_demand(value_array, bn_array, box_array, label_array, box_type, ad6_atr) =>

    atr_buffer = ad6_atr * (ad6_box_width / 10)
    box_left = array.get(bn_array, 0)
    box_right = bar_index

    var float box_top = 0.00
    var float box_bottom = 0.00
    var float poi = 0.00


    if box_type == 1
        box_top := array.get(value_array, 0)
        box_bottom := box_top - atr_buffer
        poi := (box_top + box_bottom) / 2
        poi 
    else if box_type == -1
        box_bottom := array.get(value_array, 0)
        box_top := box_bottom + atr_buffer
        poi := (box_top + box_bottom) / 2
        poi

    okay_to_draw = f_check_overlapping(poi, box_array, ad6_atr)
    // okay_to_draw = true

    //delete oldest box, and then create a new box and add it to the array
    if box_type == 1 and okay_to_draw 
        box.delete(array.get(box_array, array.size(box_array) - 1))
        f_array_add_pop(box_array, box.new(left = box_left, top = box_top, right = box_right, bottom = box_bottom, border_color = ad6_supply_outline_color, bgcolor = ad6_supply_color, extend = extend.right, text = 'SUPPLY', text_halign = text.align_center, text_valign = text.align_center, text_color = poi_label_color, text_size = size.small, xloc = xloc.bar_index,force_overlay = true))

        // box.delete(array.get(label_array, array.size(label_array) - 1)) 
        // f_array_add_pop(label_array, box.new(left = box_left, top = poi, right = box_right, bottom = poi, border_color = color.new(poi_label_color, 90), bgcolor = color.new(poi_label_color, 90), extend = extend.right, text = '', text_halign = text.align_left, text_valign = text.align_center, text_color = poi_label_color, text_size = size.small, xloc = xloc.bar_index,force_overlay = true))

    else if box_type == -1 and okay_to_draw
        box.delete(array.get(box_array, array.size(box_array) - 1))
        f_array_add_pop(box_array, box.new(left = box_left, top = box_top, right = box_right, bottom = box_bottom, border_color = demand_outline_color, bgcolor = ad6_demand_color, extend = extend.right, text = 'DEMAND', text_halign = text.align_center, text_valign = text.align_center, text_color = poi_label_color, text_size = size.small, xloc = xloc.bar_index,force_overlay = true))

        // box.delete(array.get(label_array, array.size(label_array) - 1))
        // f_array_add_pop(label_array, box.new(left = box_left, top = poi, right = box_right, bottom = poi, border_color = color.new(poi_label_color, 90), bgcolor = color.new(poi_label_color, 90), extend = extend.right, text = '', text_halign = text.align_left, text_valign = text.align_center, text_color = poi_label_color, text_size = size.small, xloc = xloc.bar_index,force_overlay = true))


//      FUNCTION TO CHANGE SUPPLY/DEMAND TO A BOS IF BROKEN 
f_sd_to_bos(box_array, bos_array, label_array, zone_type) =>

    if zone_type == 1
        for i = 0 to array.size(box_array) - 1 by 1
            level_to_break = box.get_top(array.get(box_array, i))
            // if ta.crossover(close, level_to_break)
            if close >= level_to_break
                copied_box = box.copy(array.get(box_array, i))
                f_array_add_pop(bos_array, copied_box)
                mid = (box.get_top(array.get(box_array, i)) + box.get_bottom(array.get(box_array, i))) / 2
                box.set_top(array.get(bos_array, 0), mid)
                box.set_bottom(array.get(bos_array, 0), mid)
                box.set_extend(array.get(bos_array, 0), extend.none)
                box.set_right(array.get(bos_array, 0), bar_index)
                box.set_text(array.get(bos_array, 0), 'BOS')
                box.set_border_color(array.get(bos_array, 0), bos_bear_line_color )
                box.set_border_width(array.get(bos_array, 0), 1)  
                box.set_text_color(array.get(bos_array, 0), bos_label_color) 
                box.set_text_size(array.get(bos_array, 0), size.small)
                box.set_text_halign(array.get(bos_array, 0), text.align_center) 
                box.set_text_valign(array.get(bos_array, 0), text.align_center)
                box.delete(array.get(box_array, i))
                box.delete(array.get(label_array, i))
 

    if zone_type == -1
        for i = 0 to array.size(box_array) - 1 by 1
            level_to_break = box.get_bottom(array.get(box_array, i))
            // if ta.crossunder(close, level_to_break)
            if close <= level_to_break
                copied_box = box.copy(array.get(box_array, i))
                f_array_add_pop(bos_array, copied_box)
                mid = (box.get_top(array.get(box_array, i)) + box.get_bottom(array.get(box_array, i))) / 2
                box.set_top(array.get(bos_array, 0), mid)
                box.set_bottom(array.get(bos_array, 0), mid)
                box.set_extend(array.get(bos_array, 0), extend.none)
                box.set_right(array.get(bos_array, 0), bar_index)
                box.set_text(array.get(bos_array, 0), 'BOS')
                box.set_border_color(array.get(bos_array, 0), bos_bull_line_color)
                box.set_border_width(array.get(bos_array, 0), 1) 
                box.set_text_color(array.get(bos_array, 0), bos_label_color)
                box.set_text_size(array.get(bos_array, 0), size.small)
                box.set_text_halign(array.get(bos_array, 0), text.align_center)
                box.set_text_valign(array.get(bos_array, 0), text.align_center)
                box.delete(array.get(box_array, i))
                box.delete(array.get(label_array, i))



//      FUNCTION MANAGE CURRENT BOXES BY CHANGING ENDPOINT
f_extend_box_endpoint(box_array) =>

    for i = 0 to array.size(box_array) - 1 by 1
        box.set_right(array.get(box_array, i), bar_index + 100)


//
//CALCULATIONS
//
if ad6_activate
    //      CALCULATE ad6_atr 
    ad6_atr = ta.atr(50)

    //      CALCULATE SWING HIGHS & SWING LOWS
    ad6_swing_high = ta.pivothigh(high, ad6_swing_length, ad6_swing_length)
    ad6_swing_low = ta.pivotlow(low, ad6_swing_length, ad6_swing_length)

    //      ARRAYS FOR SWING H/L & BN 
    var swing_high_values = array.new_float(5, 0.00)
    var swing_low_values = array.new_float(5, 0.00)

    var swing_high_bns = array.new_int(5, 0)
    var swing_low_bns = array.new_int(5, 0)

    //      ARRAYS FOR SUPPLY / DEMAND
    var current_supply_box = array.new_box(history_of_demand_to_keep, na)
    var current_demand_box = array.new_box(history_of_demand_to_keep, na)

    //      ARRAYS FOR SUPPLY / DEMAND POI LABELS
    var current_supply_poi = array.new_box(history_of_demand_to_keep, na)
    var current_demand_poi = array.new_box(history_of_demand_to_keep, na)

    //      ARRAYS FOR BOS
    var ad6_supply_bos = array.new_box(5, na)
    var ad6_demand_bos = array.new_box(5, na)
    //
    //END CALCULATIONS
    //

    //      NEW SWING HIGH
    if not na(ad6_swing_high)

        //MANAGE SWING HIGH VALUES
        f_array_add_pop(swing_high_values, ad6_swing_high)
        f_array_add_pop(swing_high_bns, bar_index[ad6_swing_length])
        if show_price_action_labels
            f_sh_sl_labels(swing_high_values, 1)

        f_supply_demand(swing_high_values, swing_high_bns, current_supply_box, current_supply_poi, 1, ad6_atr)

    //      NEW SWING LOW
    else if not na(ad6_swing_low)

        //MANAGE SWING LOW VALUES
        f_array_add_pop(swing_low_values, ad6_swing_low)
        f_array_add_pop(swing_low_bns, bar_index[ad6_swing_length])
        if show_price_action_labels
            f_sh_sl_labels(swing_low_values, -1)

        f_supply_demand(swing_low_values, swing_low_bns, current_demand_box, current_demand_poi, -1, ad6_atr)


    f_sd_to_bos(current_supply_box, ad6_supply_bos, current_supply_poi, 1)
    f_sd_to_bos(current_demand_box, ad6_demand_bos, current_demand_poi, -1)

    f_extend_box_endpoint(current_supply_box)
    f_extend_box_endpoint(current_demand_box)

    
    var ad6_dirUp = false
    var ad6_lastLow = high * 100
    var ad6_lastHigh = 0.0
    var ad6_timeLow = bar_index
    var ad6_timeHigh = bar_index
    var line ad6_li = na

//////////////////
whiteFomo = isup()
yelFomo = isdown()
//Remove below '//' to make it alert only once at the start of the sequence
fomoBullAlert = whiteFomo //and not whiteFomo[1] 
fomoBearAlert = yelFomo //and not yelFomo[1] 
alertcondition(fomoBullAlert, "Bullish FOMO" , "Bullish FOMO @ {{ticker}}" )
alertcondition(fomoBearAlert, "Bearish FOMO" , "Bearish FOMO @ {{ticker}}" )